Beim Herunterfahren automatisch auf lautlos stellen: Unterschied zwischen den Versionen

Aus ThinkPad-Wiki
Keine Bearbeitungszusammenfassung
Keine Bearbeitungszusammenfassung
Zeile 17: Zeile 17:


== Die Skripte ==
== Die Skripte ==
Bei diesen Skripten handelt es sich um ''Visual Basic Scripts (VBS)''. Sie nutzen den von Hause aus in Windows schon vorhandenen ''Windows Scripting Host (WSH)''. Die Dateien können einfach mit einem Texteditor erstellt und abgespeichert werden. Wichtig ist nur, dass sie die Endung ''.vbs'' erhalten.


''automute.vbs''
''automute.vbs''
Zeile 25: Zeile 27:
  ' author : buergernb
  ' author : buergernb
  '
  '
  ' Dieses Script setzt das Tool NIRCMD im Pfad "C:\nircmd" voraus.
  ' Dieses Script setzt das Tool NIRCMD im Pfad "C:\automute" voraus.
  ' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
  ' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
  '
  '
Zeile 104: Zeile 106:


[http://www.nirsoft.net/ Herstellerseite des Tools ''Nircmd'']
[http://www.nirsoft.net/ Herstellerseite des Tools ''Nircmd'']
[http://support.microsoft.com/kb/188135 Beschreibung des ''Microsoft Windows Scripting Hosts (WSH)'']

Version vom 6. Juli 2009, 00:52 Uhr

Besitzer eines R52, T43, T43p, X41 oder X41 Tablet haben dank der von IBM konzipierten und verbauten SATA-to-IDE-Bridge nicht nur das Problem nur noch wenige aktuelle Festplatten mit entsprechend großer Kapazität zu finden. Durch eine Routine im BIOS dieser Modelle wird das verwendete Laufwerk beim Start auf eine von IBM freigegebene Firmware überprüft. Wird eine solche Firmware nicht vorgefunden, quittiert dies das BIOS je nach Einstellung mit einem Pieps-Ton oder bricht den Start ganz und gar ab. Trotz dieser Fehlermeldung, dem berühmten "Error 2010", arbeitet das ThinkPad einwandfrei. Allein das Warnsignal während des Hochfahrens stört den Benutzer und es kommt schnell der Wunsch auf, das Notebook zumindest für die Startphase zum Schweigen zu bringen. Dieser Artikel behandelt eine mögliche und einfache Lösung.

Was benötigt man

Die Shutdown-Verknüpfung auf dem Desktop.
Als erstes das Tool Nircmd. Ohne dieses oder ähnliche Tools kann der Ton über die Komandozeile nicht bewußt nur ein- oder eben nur ausschalten werden.
Dann zwei VBS-Skripte: Eins wird in den Autostart kopiert (automute.vbs) oder eben dorthin verlinkt (Das ist die übersichtlichere Variante).
Das Zweite (shutdown.vbs) wird auf den Desktop kopiert oder auch hier verknüpft. Nun muss man sich als Benutzer nur daran gewöhnen, den Rechner über diese Verknüpfung herunterzufahren.
Um die Skripte für alles Benutzer auf dem Rechner arbeiten zu lassen, legt man diese unter All Users ab oder verknüpft sie in diesem Profil. Unter Windows XP sind das die Ordner
C:\Dokumente und Einstellungen\All Users\Startmenü\Programme\Autostart\

für die Datei automute.vbs und

C:\Dokumente und Einstellungen\All Users\Desktop\
für shutdown.vbs.

Die Skripte

Bei diesen Skripten handelt es sich um Visual Basic Scripts (VBS). Sie nutzen den von Hause aus in Windows schon vorhandenen Windows Scripting Host (WSH). Die Dateien können einfach mit einem Texteditor erstellt und abgespeichert werden. Wichtig ist nur, dass sie die Endung .vbs erhalten.

automute.vbs

'********************************************************************
' Logon script with MUTE OFF
'
' Version	: 1.2b (09-07-02)
' author	: buergernb
'
' Dieses Script setzt das Tool NIRCMD im Pfad "C:\automute" voraus.
' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
'
' Einfach diese VBS-Datei in den Autostart kopieren oder verknüpfen.
'********************************************************************
 
 
'Erforderlicher Aufruf für eine Shellumgebung.
'------------------------------------------
Set oShell = CreateObject("WScript.Shell")
 
 
'Schaltet den Ton ein.
'-------------------------------------------------
oShell.Run "C:\automute\nircmd.exe mutesysvolume 0"
 
 
'Trigger, der die Windows Eventschleife "abhört".
'Dabei wartet er auf ein Event vom Typ
'"Win32_PowerManagementEvent".
'-------------------------------------------------
Set colMonitoredEvents = GetObject("winmgmts:")._
ExecNotificationQuery("Select * from Win32_PowerManagementEvent") 
 
 
'Die Schleife zur Verarbeitung dieses Events.
'Gibt Win32_PowerManagementEvent die Zahl 4 zurück, 
'ist der Rechner im Begriff in den Standby- oder 
'Hibernate-Modus zu gehen. Also wird der Sound 
'ausgeschaltet. Gibt es die Zahl 7 zurück, wacht der
'Rechner gerade auf und der Ton wird nach einer best. 
'Wartezeit (hier 8000 Millisekunden) wieder eingeschaltet.  
'---------------------------------------------------
Do
   Set objLatestEvent = colMonitoredEvents.NextEvent
 
   Select Case objLatestEvent.EventType
 
     Case 4
       oShell.Run "C:\automute\nircmd.exe mutesysvolume 1", , false
 
     Case 7
       wscript.sleep 8000
       oShell.Run "C:\automute\nircmd.exe mutesysvolume 0", , false
 
   End Select
Loop

shutdown.vbs

'********************************************************************
' Shutdown script with AUTOMUTE
'
' Version	: 1.2b (09-07-02)
' author	: buergernb
'
' Dieses Script setzt das Tool NIRCMD im Pfad "C:\automute" voraus.
' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
'********************************************************************
  
 
'Erforderlicher Aufruf für eine Shellumgebung.
'------------------------------------------
Set oShell = CreateObject("WScript.Shell")
 
 
'Schaltet den Ton ab.
'-------------------------------------------------
oShell.Run "C:\automute\nircmd.exe mutesysvolume 1"
 
 
'Hier wird das Herunterfahren um 1 s verzögert. Die Zahl 
'hinter dem Schalter "-t" kann ist Wartezeit in Sekunden. Sie 
'kann zwischen 0 und 600 (Sekunden) variieren.
'-------------------------------------------------------------
oShell.Run "%systemroot%\system32\shutdown.exe -s -t 00 -f"

Links

Herstellerseite des Tools Nircmd

Beschreibung des Microsoft Windows Scripting Hosts (WSH)